Les polices de caractères au menu de Mac OS X 10.6.3

ils prennent leur temps parce que pour moi tant que la nouvelle gamme Macbook Pro/Mac Pro/Macbook Air n'est pas prête ils ne sortiront pas la 10.6.3, en revanche la 10.6.3 sortira avant l'iPad ou en même temps pour intégrer au mieux le nouveau produit d'Apple...

Avant les mises à jour étaient plus nombreuses. J'ai juste l'impression que l'iPad a été au centre de l'attention de toutes les équipes de Cupertino. Ca me désole .

Tu pourrais citer la source étayant cette information?

J'espère que cette mise à jour résoudra les problèmes de clignotement d'écran sur MacBook Pro Unibody late 2008 (voir ici).

Pour éviter de perdre un quart d'heure à remettre vos icônes en place, adoptez ce script:

--{code}
--[SCRIPT récupérer_restaurer_position_icônes]
(*
Enregistrer le script en tant que Progiciel (Application sous 10.6.x) : récupérer_restaurer_position_icônes.app
Installer dans le Dock.

Sélectionner les icônes du bureau dont la position doit pouvoir être rétablie.
Lancer le script
Cliquer le bouton "Enregistrer leur position"
Un fichier texte contenant les informations relatives à ces icônes sera créé dans le dossier défini à partir de la property 'dest'
Par défaut c'est dans "<startupVolume>:Users:<userAccount>:Library:Application Support:".

Pour remettre les icônes en place, lancer l'application et cliquer le bouton "Rétablir leur position"

--=====

Save the script as an Application Bundle (Application under 10.6.x) : récupérer_restaurer_position_icônes.app
Install it in the Dock for easy access.

Select Desktop's icons whose location must be reset when needed.
Run the script.
Click the button "Get there position".
A text file containing the datas linked to these icons will be created in the folder defined according to the property 'dest'.
Default location is : "<startupVolume>:Users:<userAccount>:Library:Application Support:".


Run the script and click the button "Reset there position" to move the icons back to their original location.

--=====

Yvan KOENIG (VALLAURIS, France)
2010/03/16
*)
--=====--=====

property dest : 3
(*
1 = liste dans : "<startupVolume>:Users:<userAccount>:Library:Preferences:"
2 = liste dans : "<startupVolume>:Users:<userAccount>:Applications:Utilities:"
3 = liste dans : "<startupVolume>:Users:<userAccount>:Library:Application Support:"
*)
property nomDuRapport : "position des icones.txt"
property rapport : {}

--=====

on run
my nettoie()
if dest = 1 then
set p2d to path to preferences as text (*
"<startupVolume>:Users:<userAccount>:Library:Preferences:" *)
else if dest = 2 then
set p2d to path to utilities folder from user domain as text (*
"<startupVolume>:Users:<userAccount>:Applications:Utilities:" *)
else
set p2d to (path to library folder from user domain as text) & "Application Support:" (*
"<startupVolume>:Users:<userAccount>:Library:Application Support:" *)
end if

set p2r to p2d & nomDuRapport
if my parleAnglais() then
set prompt to "What to do with icons ?"
set {btn1, btn2, btn3} to {"Cancel", "Get there position", "Reset there position"}
else
set prompt to "Que faire avec les icônes ?"
set {btn1, btn2, btn3} to {"Abandonner", "Enregistrer leur position", "Rétablir leur position"}
end if

set maybe to button returned of (display dialog prompt buttons {btn1, btn2, btn3} default button 3)
if maybe is btn1 then (*
maybe = btn1 *)
error number -128
else if maybe is btn2 then (*
maybe = btn2 *)
tell application "Finder"
set itms to get the selection
if itms = {} then
if my parleAnglais() then
error "You failed to select icons from the Desktop !"
else
error "Il aurait fallu sélectionner des icônes sur le bureau !"
end if
end if
repeat with itm in itms
set itm to itm as alias
set itmPos to get desktop position of item itm
if itmPos is missing value then
if my parleAnglais() then
error ("The icon “" & itm & "” isn‘t on the Desktop !")
else
error ("L‘icône « " & itm & " » n‘est pas sur le Bureau !")
end if
end if
copy (itm as text) & return & "(" & (item 1 of itmPos) & ", " & (item 2 of itmPos) & ")" to end of my rapport
end repeat
set rapport to my recolle(my rapport, return)
(*
crée un fichier texte dans le dossier "Bibliothèque:Application Support" du compte utilisateur *)
tell application "System Events"
if exists file p2r then delete file p2r
make new file at end of folder p2d with properties {name:nomDuRapport}
end tell -- System Events
write rapport to (p2r as alias)
end tell -- Finder
else (*
maybe = btn3 *)

set my rapport to paragraphs of (read file p2r)
repeat with i from 1 to ((count of rapport) - 1) by 2
try
set itm to (item i of rapport) as text
set theWords to text 2 thru -2 of item (i + 1) of rapport
set theWords to my decoupe(theWords, ",")
set thePos to {item 1 of theWords as integer, item 2 of theWords as integer}
tell application "Finder" to set desktop position of item (itm as alias) to thePos
end try
end repeat
tell application "Finder" to update folder p2d
end if
my nettoie()
end run

--=====

on nettoie()
set my rapport to {}
end nettoie

--=====

on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe

--=====

on recolle(l, d)
local t
set AppleScript's text item delimiters to d
set t to l as text
set AppleScript's text item delimiters to ""
return t
end recolle

--=====

on parleAnglais()
local z
try
tell application "Finder" to set z to localized string "AL1"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais

--=====
--[/SCRIPT]
--{code}

Yvan KOENIG (VALLAURIS, France) mercredi 17 mars 2010 18:34:39

Merci les gars !
premiere fois qu'on me donne une solution a ce probleme !
je vais essayé ca de suite
du coup maintenant j'suis trop content pour les polices de caractères de 10.6.3